//
// MADX version of ISIS upgrade ring
// Author: S. L. Sheehy, ASTeC Intense Beams Group, Rutherford Appleton Laboratory
// Date: 28112011
// Based on work by C. R. Prior and G. Rees

TITLE,'ISIS upgrade ring'; 

BEAM, PARTICLE=PROTON,ENERGY=1.738272046; //800 MeV protons, PC=1.436296031, Brho=4.88097024  
brho:=4.88097024;

QF1: QUADRUPOLE, L= 7.797400E-01, K1= 2.165703/brho;
QF2: QUADRUPOLE, L= 8.637000E-01, K1= 2.165671/brho;
QF3: QUADRUPOLE, L= 6.930000E-01, K1= 2.165671/brho;
QD1: QUADRUPOLE, L= 8.657000E-01, K1= -2.165698/brho;
QD2: QUADRUPOLE, L= 8.580000E-01, K1= -2.165671/brho;
QD3: QUADRUPOLE, L= 1.283400E+00, K1= -2.165671/brho;

HBF: SBEND,L=3.8,ANGLE=0.2792527,HGAP=0.1, FINT;  // bending magnet
RHBF1: RBEND, L=5.4446, ANGLE=0.1396263, HGAP=0.1, FINT; //bending magnet

D1: DRIFT, L=4.200;
D2: DRIFT, L=8.4;
D3: DRIFT, L=0.700;
D4: DRIFT, L=0.700;
D5: DRIFT, L=0.600;
D6: DRIFT, L=1.06346;
D7: DRIFT, L=0.6;
D8: DRIFT, L=1.00;
D9: DRIFT, L=2.7777;     


CELL1: LINE=(D1,QF1,D3,QD1,D2,QF2,D4,QD2,D6,HBF,D7,HBF,D8,QF3,D5,QD3,D5,QF3,D9);
SUPER: LINE=(CELL1, RHBF1, -CELL1);

USE, PERIOD=SUPER;
       
SELECT,FLAG=TWISS,column=name,s,betx,bety;
TWISS, file=optics.dat;

PLOT,HAXIS=S, COLOUR=100, VAXIS=BETX, BETY, DX, INTERPOLATE=TRUE;